ptrd_mod.f90

      module ptrd_mod
        use stel_kinds
        USE v3_utilities, ONLY: assert
        implicit none
 
#if defined(MPI_OPT)
        contains
 
        subroutine pdtrdf(m,nblock,Amat,Bmat,Cmat,ipivmat, desc)
        implicit none
!
!       perform LU factorization of block tridiagonal system
!
!       [A1  C1       ]   [ L1          ] [ I U1        ]
!       [B1  A2 C2    ]   [ B1 L2       ] [   I  U2     ]
!       [    B2 A3 C3 ] = [    B2 L3    ] [      I   U3 ]
!       [       B4 A4 ]   [       B3 L4 ] [          I  ]
!
! 
! L1 = A1
! L1*U1 = C1 => U1 = L1\C1
! B1*U1 + L2 = A2 =>  L2 = A2 - B1*U1
! L2*U2 = C2 =>  U2 = L2\C2
!
! Lk = Ak - B_{k-1}*U_{k-1}
! Uk = Lk\Ck
! 
!
        REAL(rprec), parameter :: one = 1.0d0
        REAL(rprec), parameter :: zero = 0.0d0
 
        integer, intent(in) :: m, nblock
        REAL(rprec), target, dimension(:,:), intent(inout) :: Amat
        REAL(rprec), target, dimension(:,:), intent(inout) :: Bmat
        REAL(rprec), target, dimension(:,:), intent(inout) :: Cmat
        integer, dimension(:,:), target, intent(inout) :: ipivmat
        integer, dimension(:), intent(in) :: desc
 
 
        integer :: k, ia,ja, ib,jb, iu,ju, ic,jc
        integer :: info, nrhs, mm,nn
        integer, dimension(:), pointer :: ipiv
        REAL(rprec) :: alpha, beta
        REAL(rprec), dimension(:), pointer :: Ak, Bkm1, Ukm1
        REAL(rprec), dimension(:), pointer :: Lk, Ck
 
 
        nullify( ak )
        nullify( bkm1 )
        nullify( ukm1 )
        nullify( lk )
        nullify( ck )
 
 
        do k=1,nblock
          if (k .ge. 2) then
!            -------------------------
!            Ak = Ak - B_{k-1}*U_{k-1}
!            -------------------------
             ak => amat(:,k)
             bkm1 => bmat(:,k-1)
             ukm1 => cmat(:,k-1)
             alpha = -one
             beta = one
             ib = 1
             jb = 1
             iu = 1
             ju = 1
             ia = 1
             ja = 1
 
             call pdgemm( 'N', 'N', m,m,m,                                    &
     &                   alpha, bkm1,ib,jb,desc,                              &
     &                          ukm1,iu,ju,desc,                              &
     &                   beta,  ak, ia,ja, desc )
          endif
 
!         ------------
!         Uk = Lk \ Ck
!         ------------
          lk => amat(:,k)
          ipiv => ipivmat(:,k)
          ia = 1
          ja = 1
          info = 0
          mm = m
          nn = m
          call pdgetrf(mm,nn,lk,ia,ja,desc,ipiv,info)
          call assert(info.eq.0,'pdtrdf: pdgetrf return info != 0')
 
          if (k .le. (nblock-1)) then
             nrhs = m
             ic = 1
             jc = 1
             ck => cmat(:,k)
             call pdgetrs('No',m,nrhs,lk,ia,ja,desc,ipiv,               &
     &                    ck,ic,jc,desc, info)
             call assert(info.eq.0,'pdtrdf: pdgetrs return info != 0')
          endif
          
 
        enddo
        return
        end subroutine pdtrdf
 
        subroutine pdtrds(m,nblock,Amat,Bmat,Cmat,ipivmat,desc,         &
     &                    nrhs, Rrhs_in,ir,jr,descRrhs_in)
        use descriptor_mod, ir1=>ir, jr1=>jr, mm1=>mm, info1=>info
        implicit none
 
 
!
!       use LU factorization of block tridiagonal system
!
!       [A1  C1       ]   [ L1          ] [ I U1        ]
!       [B1  A2 C2    ]   [ B1 L2       ] [   I  U2     ]
!       [    B2 A3 C3 ] = [    B2 L3    ] [      I   U3 ]
!       [       B4 A4 ]   [       B3 L4 ] [          I  ]
!
! 
! 
!
        integer, parameter :: idebug = 0
        REAL(rprec), parameter :: one = 1.0d0
        REAL(rprec), parameter :: zero = 0.0d0
 
        integer, intent(in) :: m, nblock
        REAL(rprec), dimension(:,:), target, intent(inout) :: Amat
        REAL(rprec), dimension(:,:), target, intent(inout) :: Bmat
        REAL(rprec), dimension(:,:), target, intent(inout) :: Cmat
        integer, dimension(:,:), target, intent(inout) :: ipivmat
        integer, dimension(:), intent(in) :: desc
 
        integer, intent(in) :: nrhs
        integer, intent(in) :: ir,jr
        REAL(rprec), dimension(:) :: Rrhs_in
        integer, dimension(:), intent(in) :: descRrhs_in
 
 
        integer :: k, info, mm,nn,kk
        integer :: ia,ja, irk, jrk, iy,jy, ix,jx, iu,ju, ib,jb
        REAL(rprec) :: alpha, beta
 
        REAL(rprec), pointer, dimension(:) :: Lk,Bkm1,Uk
        REAL(rprec), pointer, dimension(:) :: Rrhsk,Rrhskm1,Rrhskp1
        integer, pointer, dimension(:) :: ipiv
 
 
    integer :: inc1,inc2,iblock,irhs
 
    logical, parameter :: use_pdcopy = .false.
    REAL(rprec), dimension(:,:), target, allocatable :: Rrhs
    integer, dimension(DLEN_) :: descRrhs
    INTEGER           :: NUMROC
    EXTERNAL          :: numroc
 
!   -----------------------------------------------------
!   change storage to nblock copies of m by nrhs matrices
!   also to avoid alignment constraints in scalapack
!   -----------------------------------------------------
    icontxt = descrrhs_in(ctxt_)
    mb = descrrhs_in(mb_)
    nb = 1
    rsrc = 0
    csrc = 0
 
    call blacs_gridinfo( icontxt, nprow,npcol,myrow,mycol)
    locp = numroc( m, mb, myrow,rsrc,nprow)
    locq = numroc( nrhs,nb,mycol,csrc,npcol)
    lld = max(1,locp)
    call descinit(descrrhs,m,nrhs,mb,nb,rsrc,csrc,icontxt,lld,info)
    call assert(info.eq.0,'pdtrds: descinit return info != 0')
 
    ineed = max(1,locp*locq)
    allocate( rrhs(ineed,nblock),stat=ierr)
    call assert(ierr.eq.0,'pdtrds: alloc Rrhs,ierr != 0')
        rrhs = 0.0d0
 
    nullify( rrhsk )
    nullify( rrhskm1 )
    nullify( rrhskp1 )
 
!   ---------
!   copy data
!   ---------
 
    if (use_pdcopy) then
 
    do iblock=1,nblock
    do irhs=1,nrhs
      ia = (ir-1) + 1 + (iblock-1)*m
      ja = (jr-1) + irhs
      inc1 = 1
 
      ib = 1
      jb = irhs
      inc2 = 1
 
      rrhsk => rrhs(:,iblock)
      call pdcopy(m, rrhs_in,ia,ja,descrrhs_in,inc1,                    &
     &                   rrhsk,ib,jb,descrrhs,inc2 )
    enddo
    enddo
 
    else
 
    do iblock=1,nblock
      irhs = 1
      ia = (ir-1) + 1 + (iblock-1)*m
      ja = (jr-1) + irhs
      
      ib = 1
      jb = irhs
      rrhsk => rrhs(:,iblock)
      alpha = 1.0d0
      beta = 0.0d0
      call pdgeadd( 'N',m,nrhs,alpha,rrhs_in,ia,ja,descrrhs_in,           &
     &            beta, rrhsk,ib,jb,descrrhs )
    enddo
 
    endif
 
!   ----------------- 
!   L*U*x = r
!   (1) solve L*y = r
!   (2) solve U*x = y
!   ----------------- 
        nullify(lk)
        nullify(bkm1)
        nullify(uk)
        nullify(ipiv)
 
        icontxt = desc(ctxt_)
    call blacs_gridinfo(icontxt, nprow,npcol,myrow,mycol)
        isroot = (myrow.eq.0).and.(mycol.eq.0)
 
!   --------------------------------
!  (1) solve L*y = r
!
!   [L1             ] [ y1 ]   [ r1 ]
!   [B1  L2         ] [ y2 ]   [ r2 ]
!   [    B2  L3     ] [ y3 ] = [ r3 ]
!   [        B3  L4 ] [ y4 ]   [ r4 ]
!
!
!   y1 = L1\r1
!   y2 = L2\( r2 - B1*y1 )
!   y3 = L3\( r3 - B2*y2 )
!   y4 = L4\( r4 - B3*y3 )
!
!   yk = Lk\( rk - B_{k-1}*y_{k-1} )
!   --------------------------------
          if (isroot .and. (idebug.ge.1)) then
             write(*,*) 'pdtrds 77: m,nblock,nrhs ',m,nblock,nrhs
             write(*,*) 'descRrhs_in(M_) ',descrrhs_in(m_)
             write(*,*) 'descRrhs_in(N_) ',descrrhs_in(n_)
             write(*,*) 'descRrhs_in(MB_) ',descrrhs_in(mb_)
             write(*,*) 'descRrhs_in(NB_) ',descrrhs_in(nb_)
          endif
 
        do k=1,nblock
          if (k .ge. 2) then
!           --------------------------
!           rk <- rk - B_{k-1}*y_{k-1}  
!           --------------------------
            bkm1 => bmat(:,k-1)
 
            alpha = -one
            beta = one
            mm = m
            nn = nrhs
            kk = m
            ib = 1
            jb = 1
 
            iy = 1
            jy = 1
            irk = 1
            jrk = 1
        rrhsk => rrhs(:,k)
        rrhskm1 => rrhs(:,k-1)
 
            call pdgemm( 'N', 'N', mm,nn,kk,                                 &
     &          alpha,  bkm1, ib,jb, desc,                                   &
     &                  rrhskm1, iy,jy, descrrhs,                            &
     &          beta,   rrhsk, irk,jrk,descrrhs )
          endif
 
!         ------------
!         yk = Lk \ rk
!         ------------
 
          lk => amat(:,k)
          ia = 1
          ja = 1
          ipiv => ipivmat(:,k)
 
      rrhsk => rrhs(:,k)
          jrk = 1
          irk = 1
 
          info = 0
          if (isroot .and. (idebug.ge.1)) then
             write(*,*) 'pdtrds 106: k,irk,jrk ',k,irk,jrk
          endif
          call pdgetrs( 'N', m,nrhs, lk,ia,ja,desc, ipiv,               &
     &                  rrhsk,irk,jrk,descrrhs,info)
          call assert(info.eq.0,'pdtrds: pdgetrs return info != 0')
 
        enddo
 
 
!  (2)  solve U*x = y
!
! [I  U1         ]   [ x1 ]   [ y1 ]
! [   I   U2     ]   [ x2 ]   [ y2 ]
! [       I   U3 ]   [ x3 ] = [ y3 ]
! [           I  ]   [ x4 ]   [ y4 ]
!
!
! x4 = y4
! x3 = y3 - U3*y4
! x2 = y2 - U2*y3
! x1 = y1 - U1*y2
!
! xk = yk - Uk*x_{k+1}
!
 
        do k=nblock-1,1,-1
!          --------------------
!          xk = yk - Uk*x_{k+1}
!          --------------------
           alpha = -one
           beta = one
 
           mm = m
           nn = nrhs
           kk = m
           uk => cmat(:,k)
           iu = 1
           ju = 1
 
           ix = 1
           jx = 1
           irk = 1
           jrk = 1
 
       rrhskp1 => rrhs(:,k+1)
       rrhsk => rrhs(:,k)
 
           call pdgemm( 'N','N', mm,nn,kk,                                     &
     &                 alpha,  uk,iu,ju,desc,                                  &
     &                         rrhskp1,ix,jx,descrrhs,                         &
     &                 beta,   rrhsk,irk,jrk,descrrhs )
         enddo
 
!   ----------------
!   copy results out
!   ----------------
 
    if (use_pdcopy) then
 
    do iblock=1,nblock
    do irhs=1,nrhs
      ia = (ir-1) + 1 + (iblock-1)*m
      ja = (jr-1) + irhs
      inc1 = 1
 
      ib = 1
      jb = irhs
      inc2 = 1
 
      rrhsk => rrhs(:,iblock)
          call pdcopy(m,rrhsk,ib,jb,descrrhs,inc2,                          &
     &                  rrhs_in,ia,ja,descrrhs_in,inc1)
    enddo
    enddo
 
    else
 
    do iblock=1,nblock
      irhs = 1
      ia = (ir-1) + 1 + (iblock-1)*m
      ja = (jr-1) + irhs
      
      ib = 1
      jb = irhs
      rrhsk => rrhs(:,iblock)
      alpha = 1.0d0
      beta = 0.0d0
 
      call pdgeadd('N',m,nrhs,alpha,rrhsk,ib,jb,descrrhs,               &
     &                            beta,rrhs_in,ia,ja,descrrhs_in)
    enddo
 
    endif
    deallocate( rrhs, stat=ierr)
    call assert(ierr.eq.0,'pdtrds: dealloc Rhs ')
      
 
        return
        end subroutine pdtrds
 
#if defined(NEED_TOOLS)      
      SUBROUTINE pdgetrs( TRANS, N, NRHS, A, IA, JA, DESCA, IPIV, B,    &
     &                    IB, JB, DESCB, INFO )
!
!  -- ScaLAPACK routine (version 1.7) --
!     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
!     and University of California, Berkeley.
!     May 1, 1997
!
!     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            IA, IB, INFO, JA, JB, N, NRHS
!     ..
!     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCB( * ), IPIV( * )
      REAL(dp)   A( * ), B( * )
!     ..
!
!  Purpose
!  =======
!
!  PDGETRS solves a system of distributed linear equations
!
!                   op( sub( A ) ) * X = sub( B )
!
!  with a general N-by-N distributed matrix sub( A ) using the LU
!  factorization computed by PDGETRF.
!  sub( A ) denotes A(IA:IA+N-1,JA:JA+N-1), op( A ) = A or A**T and
!  sub( B ) denotes B(IB:IB+N-1,JB:JB+NRHS-1).
!
!  Notes
!  =====
!
!  Each global data object is described by an associated description
!  vector.  This vector stores the information required to establish
!  the mapping between an object element and its corresponding process
!  and memory location.
!
!  Let A be a generic term for any 2D block cyclicly distributed array.
!  Such a global array has an associated description vector DESCA.
!  In the following comments, the character _ should be read as
!  "of the global array".
!
!  NOTATION        STORED IN      EXPLANATION
!  --------------- -------------- --------------------------------------
!  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
!                                 DTYPE_A = 1.
!  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
!                                 the BLACS process grid A is distribu-
!                                 ted over. The context itself is glo-
!                                 bal, but the handle (the integer
!                                 value) may vary.
!  M_A    (global) DESCA( M_ )    The number of rows in the global
!                                 array A.
!  N_A    (global) DESCA( N_ )    The number of columns in the global
!                                 array A.
!  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
!                                 the rows of the array.
!  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
!                                 the columns of the array.
!  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
!                                 row of the array A is distributed.
!  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
!                                 first column of the array A is
!                                 distributed.
!  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
!                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
!
!  Let K be the number of rows or columns of a distributed matrix,
!  and assume that its process grid has dimension p x q.
!  LOCr( K ) denotes the number of elements of K that a process
!  would receive if K were distributed over the p processes of its
!  process column.
!  Similarly, LOCc( K ) denotes the number of elements of K that a
!  process would receive if K were distributed over the q processes of
!  its process row.
!  The values of LOCr() and LOCc() may be determined via a call to the
!  ScaLAPACK tool function, NUMROC:
!          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
!          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
!  An upper bound for these quantities may be computed by:
!          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
!          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
!
!  This routine requires square block data decomposition ( MB_A=NB_A ).
!
!  Arguments
!  =========
!
!  TRANS   (global input) CHARACTER
!          Specifies the form of the system of equations:
!          = 'N':  sub( A )    * X = sub( B )  (No transpose)
!          = 'T':  sub( A )**T * X = sub( B )  (Transpose)
!          = 'C':  sub( A )**T * X = sub( B )  (Transpose)
!
!  N       (global input) INTEGER
!          The number of rows and columns to be operated on, i.e. the
!          order of the distributed submatrix sub( A ). N >= 0.
!
!  NRHS    (global input) INTEGER
!          The number of right hand sides, i.e., the number of columns
!          of the distributed submatrix sub( B ). NRHS >= 0.
!
!  A       (local input) REAL(dp) pointer into the local
!          memory to an array of dimension (LLD_A, LOCc(JA+N-1)).
!          On entry, this array contains the local pieces of the factors
!          L and U from the factorization sub( A ) = P!L!U; the unit
!          diagonal elements of L are not stored.
!
!  IA      (global input) INTEGER
!          The row index in the global array A indicating the first
!          row of sub( A ).
!
!  JA      (global input) INTEGER
!          The column index in the global array A indicating the
!          first column of sub( A ).
!
!  DESCA   (global and local input) INTEGER array of dimension DLEN_.
!          The array descriptor for the distributed matrix A.
!
!  IPIV    (local input) INTEGER array, dimension ( LOCr(M_A)+MB_A )
!          This array contains the pivoting information.
!          IPIV(i) -> The global row local row i was swapped with.
!          This array is tied to the distributed matrix A.
!
!  B       (local input/local output) REAL(dp) pointer into the
!          local memory to an array of dimension
!          (LLD_B,LOCc(JB+NRHS-1)).  On entry, the right hand sides
!          sub( B ). On exit, sub( B ) is overwritten by the solution
!          distributed matrix X.
!
!  IB      (global input) INTEGER
!          The row index in the global array B indicating the first
!          row of sub( B ).
!
!  JB      (global input) INTEGER
!          The column index in the global array B indicating the
!          first column of sub( B ).
!
!  DESCB   (global and local input) INTEGER array of dimension DLEN_.
!          The array descriptor for the distributed matrix B.
!
!  INFO    (global output) INTEGER
!          = 0:  successful exit
!          < 0:  If the i-th argument is an array and the j-entry had
!                an illegal value, then INFO = -(i!100+j), if the i-th
!                argument is a scalar and had an illegal value, then
!                INFO = -i.
!
!  =====================================================================
!
!     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,   &
     &                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,   &
     &                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,  &
     &                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL(dp)   ONE
      PARAMETER          ( ONE = 1.0d+0 )
!     ..
!     .. Local Scalars ..
      LOGICAL            NOTRAN
      INTEGER            IAROW, IBROW, ICOFFA, ICTXT, IROFFA, IROFFB,    &
     &                   mycol, myrow, npcol, nprow
!     ..
!     .. Local Arrays ..
      INTEGER            DESCIP( DLEN_ ), IDUM1( 1 ), IDUM2( 1 )
!     ..
!     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, chk1mat, descset, pchk2mat,     &
     &                   pdlapiv, pdtrsm, pxerbla
!     ..
!     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            INDXG2P, NUMROC
      EXTERNAL           indxg2p, lsame, numroc
!     ..
!     .. Intrinsic Functions ..
      INTRINSIC          ichar, mod
!     ..
!     .. Executable Statements ..
!
!     Get grid parameters
!
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
!
!     Test the input parameters
!
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -(700+ctxt_)
      ELSE
         notran = lsame( trans, 'N' )
         CALL chk1mat( n, 2, n, 2, ia, ja, desca, 7, info )
         CALL chk1mat( n, 2, nrhs, 3, ib, jb, descb, 12, info )
         IF( info.EQ.0 ) THEN
            iarow = indxg2p( ia, desca( mb_ ), myrow, desca( rsrc_ ),   &
     &                       nprow )
            ibrow = indxg2p( ib, descb( mb_ ), myrow, descb( rsrc_ ),   &
     &                       nprow )
            iroffa = mod( ia-1, desca( mb_ ) )
            icoffa = mod( ja-1, desca( nb_ ) )
            iroffb = mod( ib-1, descb( mb_ ) )
            IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) .AND. .NOT.  &
     &         lsame( trans, 'C' ) ) THEN
               info = -1
            ELSE IF( iroffa.NE.0 ) THEN
               info = -5
            ELSE IF( icoffa.NE.0 ) THEN
               info = -6
            ELSE IF( desca( mb_ ).NE.desca( nb_ ) ) THEN
               info = -(700+nb_)
!            ELSE IF( IROFFB.NE.0 .OR. IBROW.NE.IAROW ) THEN
!               INFO = -10
            ELSE IF( descb( mb_ ).NE.desca( nb_ ) ) THEN
               info = -(1200+nb_)
            ELSE IF( ictxt.NE.descb( ctxt_ ) ) THEN
               info = -(1200+ctxt_)
            END IF
         END IF
         IF( notran ) THEN
            idum1( 1 ) = ichar( 'N' )
         ELSE IF( lsame( trans, 'T' ) ) THEN
            idum1( 1 ) = ichar( 'T' )
         ELSE
            idum1( 1 ) = ichar( 'C' )
         END IF
         idum2( 1 ) = 1
         CALL pchk2mat( n, 2, n, 2, ia, ja, desca, 7, n, 2, nrhs, 3,    &
     &                  ib, jb, descb, 12, 1, idum1, idum2, info )
      END IF
 
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PDGETRS', -info )
         RETURN
      END IF
!
!     Quick return if possible
!
      IF( n.EQ.0 .OR. nrhs.EQ.0 ) RETURN
 
      CALL descset( descip, desca( m_ ) + desca( mb_ )*nprow, 1,        &
     &              desca( mb_ ), 1, desca( rsrc_ ), mycol, ictxt,      &
     &              desca( mb_ ) + numroc( desca( m_ ), desca( mb_ ),   &
     &              myrow, desca( rsrc_ ), nprow ) )
 
      IF( notran ) THEN
!
!        Solve sub( A ) * X = sub( B ).
!
!        Apply row interchanges to the right hand sides.
!
         CALL pdlapiv( 'Forward', 'Row', 'Col', n, nrhs, b, ib, jb,     &
     &                 descb, ipiv, ia, 1, descip, idum1 )
!
!        Solve L*X = sub( B ), overwriting sub( B ) with X.
!
         CALL pdtrsm( 'Left', 'Lower', 'No transpose', 'Unit', n, nrhs, &
     &                one, a, ia, ja, desca, b, ib, jb, descb )
!
!        Solve U*X = sub( B ), overwriting sub( B ) with X.
!
         CALL pdtrsm( 'Left', 'Upper', 'No transpose', 'Non-unit', n,   &
     &                nrhs, one, a, ia, ja, desca, b, ib, jb, descb )
      ELSE
!
!        Solve sub( A )' * X = sub( B ).
!
!        Solve U'*X = sub( B ), overwriting sub( B ) with X.
!
         CALL pdtrsm( 'Left', 'Upper', 'Transpose', 'Non-unit', n, nrhs, &
     &                one, a, ia, ja, desca, b, ib, jb, descb )
!
!        Solve L'*X = sub( B ), overwriting sub( B ) with X.
!
         CALL pdtrsm( 'Left', 'Lower', 'Transpose', 'Unit', n, nrhs,    &
     &                one, a, ia, ja, desca, b, ib, jb, descb )
!
!        Apply row interchanges to the solution vectors.
!
         CALL pdlapiv( 'Backward', 'Row', 'Col', n, nrhs, b, ib, jb,    &
     &                 descb, ipiv, ia, 1, descip, idum1 )
 
      END IF
 
      RETURN
 
!     End of PDGETRS
 
      END SUBROUTINE pdgetrs
      
      SUBROUTINE pdelget( SCOPE, TOP, ALPHA, A, IA, JA, DESCA )
      use descriptor_mod, desca_x=>desca
      implicit none
!
!  -- ScaLAPACK tools routine (version 1.7) --
!     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
!     and University of California, Berkeley.
!     May 1, 1997
!
!     .. Scalar Arguments ..
      CHARACTER*1        SCOPE, TOP
      INTEGER            IA, JA
      REAL(dp)   ALPHA
!     ..
!     .. Array arguments ..
      INTEGER            DESCA( * )
      REAL(dp)   A( * )
!     ..
!
!  Purpose
!  =======
!
!  PDELGET sets alpha to the distributed matrix entry A( IA, JA ).
!  The value of alpha is set according to the scope.
!
!  Notes
!  =====
!
!  Each global data object is described by an associated description
!  vector.  This vector stores the information required to establish
!  the mapping between an object element and its corresponding process
!  and memory location.
!
!  Let A be a generic term for any 2D block cyclicly distributed array.
!  Such a global array has an associated description vector DESCA.
!  In the following comments, the character _ should be read as
!  "of the global array".
!
!  NOTATION        STORED IN      EXPLANATION
!  --------------- -------------- --------------------------------------
!  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
!                                 DTYPE_A = 1.
!  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
!                                 the BLACS process grid A is distribu-
!                                 ted over. The context itself is glo-
!                                 bal, but the handle (the integer
!                                 value) may vary.
!  M_A    (global) DESCA( M_ )    The number of rows in the global
!                                 array A.
!  N_A    (global) DESCA( N_ )    The number of columns in the global
!                                 array A.
!  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
!                                 the rows of the array.
!  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
!                                 the columns of the array.
!  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
!                                 row of the array A is distributed.
!  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
!                                 first column of the array A is
!                                 distributed.
!  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
!                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
!
!  Let K be the number of rows or columns of a distributed matrix,
!  and assume that its process grid has dimension p x q.
!  LOCr( K ) denotes the number of elements of K that a process
!  would receive if K were distributed over the p processes of its
!  process column.
!  Similarly, LOCc( K ) denotes the number of elements of K that a
!  process would receive if K were distributed over the q processes of
!  its process row.
!  The values of LOCr() and LOCc() may be determined via a call to the
!  ScaLAPACK tool function, NUMROC:
!          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
!          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
!  An upper bound for these quantities may be computed by:
!          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )!MB_A
!          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )!NB_A
!
!  Arguments
!  =========
!
!  SCOPE   (global input) CHARACTER*1
!          The BLACS scope in which alpha is updated.
!          If SCOPE = 'R', alpha is updated only in the process row
!                          containing A( IA, JA ),
!          If SCOPE = 'C', alpha is updated only in the process column
!                          containing A( IA, JA ),
!          If SCOPE = 'A', alpha is updated in all the processes of the
!                          grid,
!          otherwise alpha is updated only in the process containing
!           A( IA, JA ).
!
!  TOP     (global input) CHARACTER!1
!          The topology to be used if broadcast is needed.
!
!  ALPHA   (global output) DOUBLE PRECISION, the scalar alpha.
!
!  A       (local input) REAL(dp) pointer into the local memory
!          to an array of dimension (LLD_A,!) containing the local
!          pieces of the distributed matrix A.
!
!  IA      (global input) INTEGER
!          The row index in the global array A indicating the first
!          row of sub( A ).
!
!  JA      (global input) INTEGER
!          The column index in the global array A indicating the
!          first column of sub( A ).
!
!  DESCA   (global and local input) INTEGER array of dimension DLEN_.
!          The array descriptor for the distributed matrix A.
!
!  =====================================================================
!
!     .. Parameters ..
!      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
!     $                   LLD_, MB_, M_, NB_, N_, RSRC_
!      PARAMETER          ( BLOCK_CYCLIC_2D = 1, DLEN_ = 9, DTYPE_ = 1,
!     $                     CTXT_ = 2, M_ = 3, N_ = 4, MB_ = 5, NB_ = 6,
!     $                     RSRC_ = 7, CSRC_ = 8, LLD_ = 9 )
      REAL(dp)   ZERO
      PARAMETER          ( ZERO = 0.0d+0 )
!     ..
!     .. Local Scalars ..
      INTEGER            IACOL, IAROW, ICTXT, IIA, IOFFA, JJA  !, MYCOL, MYROW, NPCOL, NPROW
!     ..
!     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, dgebr2d, dgebs2d, infog2l
!     ..
!     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           LSAME
!     ..
!     .. Executable Statements ..
!
!     Get grid parameters.
!
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
!
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, iia, jja,&
                    iarow, iacol )
!
      alpha = zero
!
      IF( lsame( scope, 'R' ) ) THEN
         IF( myrow.EQ.iarow ) THEN
            IF( mycol.EQ.iacol ) THEN
               ioffa = iia+(jja-1)*desca( lld_ )
               CALL dgebs2d( ictxt, scope, top, 1, 1, a( ioffa ), 1 )
               alpha = a( ioffa )
            ELSE
               CALL dgebr2d( ictxt, scope, top, 1, 1, alpha, 1,         &
                             iarow, iacol )
            END IF
         END IF
      ELSE IF( lsame( scope, 'C' ) ) THEN
         IF( mycol.EQ.iacol ) THEN
            IF( myrow.EQ.iarow ) THEN
               ioffa = iia+(jja-1)*desca( lld_ )
               CALL dgebs2d( ictxt, scope, top, 1, 1, a( ioffa ), 1 )
               alpha = a( ioffa )
            ELSE
               CALL dgebr2d( ictxt, scope, top, 1, 1, alpha, 1,         &
                             iarow, iacol )
            END IF
         END IF
      ELSE IF( lsame( scope, 'A' ) ) THEN
         IF( ( myrow.EQ.iarow ).AND.( mycol.EQ.iacol ) ) THEN
            ioffa = iia+(jja-1)*desca( lld_ )
            CALL dgebs2d( ictxt, scope, top, 1, 1, a( ioffa ), 1 )
            alpha = a( ioffa )
         ELSE
            CALL dgebr2d( ictxt, scope, top, 1, 1, alpha, 1,            &
                          iarow, iacol )
         END IF
      ELSE
         IF( myrow.EQ.iarow .AND. mycol.EQ.iacol )                      &
            alpha = a( iia+(jja-1)*desca( lld_ ) )
      END IF
!
      RETURN
!
!     End of PDELGET
!
      END
      
      SUBROUTINE pdelset( A, IA, JA, DESCA, ALPHA )
      use descriptor_mod, desca_x=>desca
      implicit none
!
!  -- ScaLAPACK tools routine (version 1.7) --
!     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
!     and University of California, Berkeley.
!     May 1, 1997
!
!     .. Scalar Arguments ..
      INTEGER            IA, JA
      REAL(dp)   ALPHA
!     ..
!     .. Array arguments ..
      INTEGER            DESCA( * )
      REAL(dp)   A( * )
!     ..
!
!  Purpose
!  =======
!
!  PDELSET sets the distributed matrix entry A( IA, JA ) to ALPHA.
!
!  Notes
!  =====
!
!  Each global data object is described by an associated description
!  vector.  This vector stores the information required to establish
!  the mapping between an object element and its corresponding process
!  and memory location.
!
!  Let A be a generic term for any 2D block cyclicly distributed array.
!  Such a global array has an associated description vector DESCA.
!  In the following comments, the character _ should be read as
!  "of the global array".
!
!  NOTATION        STORED IN      EXPLANATION
!  --------------- -------------- --------------------------------------
!  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
!                                 DTYPE_A = 1.
!  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
!                                 the BLACS process grid A is distribu-
!                                 ted over. The context itself is glo-
!                                 bal, but the handle (the integer
!                                 value) may vary.
!  M_A    (global) DESCA( M_ )    The number of rows in the global
!                                 array A.
!  N_A    (global) DESCA( N_ )    The number of columns in the global
!                                 array A.
!  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
!                                 the rows of the array.
!  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
!                                 the columns of the array.
!  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
!                                 row of the array A is distributed.
!  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
!                                 first column of the array A is
!                                 distributed.
!  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
!                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
!
!  Let K be the number of rows or columns of a distributed matrix,
!  and assume that its process grid has dimension p x q.
!  LOCr( K ) denotes the number of elements of K that a process
!  would receive if K were distributed over the p processes of its
!  process column.
!  Similarly, LOCc( K ) denotes the number of elements of K that a
!  process would receive if K were distributed over the q processes of
!  its process row.
!  The values of LOCr() and LOCc() may be determined via a call to the
!  ScaLAPACK tool function, NUMROC:
!          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
!          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
!  An upper bound for these quantities may be computed by:
!          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
!          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
!
!  Arguments
!  =========
!
!  A       (local output) REAL(dp) pointer into the local memory
!          to an array of dimension (LLD_A,*) containing the local
!          pieces of the distributed matrix A.
!
!  IA      (global input) INTEGER
!          The row index in the global array A indicating the first
!          row of sub( A ).
!
!  JA      (global input) INTEGER
!          The column index in the global array A indicating the
!          first column of sub( A ).
!
!  DESCA   (global and local input) INTEGER array of dimension DLEN_.
!          The array descriptor for the distributed matrix A.
!
!  ALPHA   (local input) DOUBLE PRECISION
!          The scalar alpha.
!
!  =====================================================================
!
!     .. Parameters ..
!      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
!     $                   LLD_, MB_, M_, NB_, N_, RSRC_
!      PARAMETER          ( BLOCK_CYCLIC_2D = 1, DLEN_ = 9, DTYPE_ = 1,
!     $                     CTXT_ = 2, M_ = 3, N_ = 4, MB_ = 5, NB_ = 6,
!     $                     RSRC_ = 7, CSRC_ = 8, LLD_ = 9 )
!     ..
!     .. Local Scalars ..
      INTEGER            IACOL, IAROW, IIA, JJA   !, MYCOL, MYROW, NPCOL,  NPROW
!     ..
!     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, infog2l
!     ..
!     .. Executable Statements ..
!
!     Get grid parameters.
!
      CALL blacs_gridinfo( desca( ctxt_ ), nprow, npcol, myrow, mycol )
!
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, iia, jja,&
                    iarow, iacol )
!
      IF( myrow.EQ.iarow .AND. mycol.EQ.iacol )                         &
         a( iia+(jja-1)*desca( lld_ ) ) = alpha
!
      RETURN
!
!     End of PDELSET
!
      END
#endif
     
#endif
        
      end module ptrd_mod