drandn.f

C**********************************************************************
C
      SUBROUTINE drandn (N,DX,SEED)
      USE stel_kinds, ONLY: rprec
      IMPLICIT NONE
C
C     Purpose:
C     Fills the vector DX with random numbers  between 0 and 1.  If the
C     SEED is given, it should be odd and positive.  The generator is a
C     fairly unsophisticated one, from Pearson's  "Numerical methods in
C     engineering and science" book.
C
C     Parameters:
C     N    = the dimension of the vector (input).
C     DX   = the vector to fill with random numbers (output).
C     SEED = the seed for the generator (input).
C
C     Noel M. Nachtigal
C     April 23, 1993
C
C**********************************************************************
C
      INTRINSIC dble, abs, mod
C
      INTEGER N, SEED
      REAL(rprec) DX(N)
C
C     Local variables.
C
      INTEGER I, J
C
C     Local variables that are saved from one call to the next.
C
      REAL(rprec) DMAX
      INTEGER :: IM=0, imax, is
      SAVE dmax, im, imax, is
C      DATA IM/0/
C
C     Initialize the generator data.
C
      IF (im.EQ.0) THEN
         j  = 0
         im = 1
         DO 10 i = 1, 31
            j = j + 1
            IF (im*2.LE.im) GO TO 20
            im = im * 2
 10      CONTINUE
 20      imax = (im-1) * 2 + 1
         dmax = imax
         DO 30 i = 1, mod(j,3)
            j = j - 1
            im = im / 2
 30      CONTINUE
         im = im + 5
         is = abs(mod(im*30107,imax))
      END IF
C
C     Check whether we have a new seed.
C
      IF (seed.GT.0) is = (seed / 2) * 2 + 1
C
C     Here goes the rest.
C
      DO 40 i = 1, n
         dx(i) = dble(is) / dmax
         is    = abs(mod(im*is,imax))
 40   CONTINUE
C
      RETURN
      END
C
C**********************************************************************