limiter_grid.f

Go to the documentation of this file.

!*******************************************************************************
!
!  Note separating the Doxygen comment block here so detailed decription is
!  found in the Module not the file.
!
!*******************************************************************************
 
      MODULE limiter_grid
      USE stel_kinds
      USE mpi_inc
      USE profiler
      USE limiter
 
      IMPLICIT NONE
 
!*******************************************************************************
!  limiter_grid module parameters
!*******************************************************************************
      CHARACTER (len=*), PARAMETER :: nc_r0         = 'r0'
      CHARACTER (len=*), PARAMETER :: nc_dr         = 'dr'
      CHARACTER (len=*), PARAMETER :: nc_z0         = 'z0'
      CHARACTER (len=*), PARAMETER :: nc_dz         = 'dz'
      CHARACTER (len=*), PARAMETER :: nc_phi_angles = 'phi_angles'
      CHARACTER (len=*), PARAMETER :: nc_iso_grids  = 'iso_grids'
 
!*******************************************************************************
!  DERIVED-TYPE DECLARATIONS
!  1) limiter_grid base class
!
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      TYPE, EXTENDS(limiter_class) :: limiter_grid_class
         REAL (rprec), DIMENSION(:,:,:), POINTER :: grid => null()
         REAL (rprec), DIMENSION(:), POINTER     :: rgrid => null()
         REAL (rprec), DIMENSION(:), POINTER     :: zgrid => null()
      CONTAINS
         PROCEDURE                          ::                                 &
     &      get_max_fval => limiter_grid_get_max_fval
         PROCEDURE                          ::                                 &
     &      get_type => limiter_grid_get_type
      END TYPE
 
!*******************************************************************************
!  INTERFACE BLOCKS
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      INTERFACE limiter_grid_class
         MODULE PROCEDURE limiter_grid_construct
      END INTERFACE
 
      CONTAINS
!*******************************************************************************
!  CONSTRUCTION SUBROUTINES
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION limiter_grid_construct(lgrid_file, on_edge)
      USE ezcdf
      USE v3_utilities
 
      IMPLICIT NONE
 
!  Declare Arguments
      class(limiter_grid_class), POINTER :: limiter_grid_construct
      CHARACTER (len=*), INTENT(in)       :: lgrid_file
      LOGICAL, INTENT(in)                 :: on_edge
 
!  local variables
      REAL (rprec)                        :: r0
      REAL (rprec)                        :: dr
      REAL (rprec)                        :: z0
      REAL (rprec)                        :: dz
      INTEGER                             :: lgrid_iou
      INTEGER                             :: status
      INTEGER, DIMENSION(3)               :: dim_lengths
      INTEGER                             :: i
      REAL (rprec)                        :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      ALLOCATE(limiter_grid_construct)
 
      CALL cdf_open(lgrid_iou, trim(lgrid_file), 'r', status)
      CALL assert_eq(0, status, 'limiter_grid_construct: ' //                  &
     &               'failed to open ', trim(lgrid_file))
 
      CALL cdf_read(lgrid_iou, nc_r0, r0)
      CALL cdf_read(lgrid_iou, nc_dr, dr)
      CALL cdf_read(lgrid_iou, nc_z0, z0)
      CALL cdf_read(lgrid_iou, nc_dz, dz)
 
      CALL cdf_inquire(lgrid_iou, nc_phi_angles, dim_lengths)
      ALLOCATE(limiter_grid_construct%phi(dim_lengths(1)))
      CALL cdf_read(lgrid_iou, nc_phi_angles,                                  &
     &              limiter_grid_construct%phi)
 
      CALL cdf_inquire(lgrid_iou, nc_iso_grids, dim_lengths)
      ALLOCATE(limiter_grid_construct%grid(dim_lengths(1),                     &
     &                                     dim_lengths(2),                     &
     &                                     dim_lengths(3)))
      CALL cdf_read(lgrid_iou, nc_iso_grids,                                   &
     &              limiter_grid_construct%grid)
 
      CALL cdf_close(lgrid_iou)
 
      ALLOCATE(limiter_grid_construct%rgrid(dim_lengths(1)))
      DO i = 1, dim_lengths(1)
         limiter_grid_construct%rgrid(i) = (i - 1)*dr + r0
      END DO
      ALLOCATE(limiter_grid_construct%zgrid(dim_lengths(2)))
      DO i = 1, dim_lengths(2)
         limiter_grid_construct%zgrid(i) = (i - 1)*dz + z0
      END DO
 
      CALL profiler_set_stop_time('limiter_grid_construct', start_time)
 
      END FUNCTION
 
!*******************************************************************************
!  DESTRUCTION SUBROUTINES
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      SUBROUTINE limiter_grid_destruct(this)
 
!  Declare Arguments
      TYPE (limiter_grid_class), POINTER :: this
 
!  Start of executable code
      IF (ASSOCIATED(this%phi)) THEN
         DEALLOCATE(this%phi)
         this%phi => null()
      END IF
 
      IF (ASSOCIATED(this%grid)) THEN
         DEALLOCATE(this%grid)
         this%grid => null()
      END IF
 
      IF (ASSOCIATED(this%rgrid)) THEN
         DEALLOCATE(this%rgrid)
         this%rgrid => null()
      END IF
 
      IF (ASSOCIATED(this%zgrid)) THEN
         DEALLOCATE(this%zgrid)
         this%zgrid => null()
      END IF
 
      END SUBROUTINE
 
!*******************************************************************************
!  GETTER SUBROUTINES
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION limiter_grid_get_max_fval(this, num_theta,  phi_index,          &
     &                                   r, z, rphiz_at_max)
      USE bivariate
 
      IMPLICIT NONE
 
!  Declare Arguments
      REAL (rprec) :: limiter_grid_get_max_fval
      class(limiter_grid_class), INTENT(in)  :: this
      INTEGER, INTENT(in)                     :: num_theta
      INTEGER, INTENT(in)                     :: phi_index
      REAL (rprec), DIMENSION(:), INTENT(in)  :: r
      REAL (rprec), DIMENSION(:), INTENT(in)  :: z
      REAL (rprec), DIMENSION(3), INTENT(out) :: rphiz_at_max
 
!  local variables
      TYPE (bivariate_type), POINTER          :: bivariate_object
      INTEGER                                 :: index
      REAL (rprec), DIMENSION(:), ALLOCATABLE :: fval
      REAL (rprec)                            :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      limiter_grid_get_max_fval = -1.0e10
      rphiz_at_max = 0.0
 
      ALLOCATE(fval(num_theta))
      bivariate_object => bivariate_construct(1, num_theta)
 
      CALL bivariate_set_grids(bivariate_object, r, z, this%rgrid,             &
     &                         this%zgrid)
      CALL bivariate_get_4pt(bivariate_object,                                 &
     &                       this%grid(:,:,phi_index), fval)
 
      index = maxloc(fval, 1)
      IF (fval(index) .gt. limiter_grid_get_max_fval) THEN
         limiter_grid_get_max_fval = fval(index)
          rphiz_at_max = (/ r(index), this%phi(phi_index),  z(index) /)
      END IF
 
      CALL bivariate_destruct(bivariate_object)
      DEALLOCATE(fval)
 
      CALL profiler_set_stop_time('limiter_grid_get_max_fval',                 &
     &                            start_time)
 
      END FUNCTION
 
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION limiter_grid_get_type(this)
      USE data_parameters
 
      IMPLICIT NONE
 
!  Declare Arguments
      CHARACTER (len=data_name_length) :: limiter_grid_get_type
      class(limiter_grid_class), INTENT(in) :: this
 
!  local variables
      REAL (rprec)                           :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      limiter_grid_get_type =                                                  &
     &   trim(this%limiter_class%get_type()) // 'grid'
 
      CALL profiler_set_stop_time('limiter_grid_get_type',                     &
     &                            start_time)
 
      END FUNCTION
 
      END MODULE