limiter_iso_T.f

Go to the documentation of this file.

!*******************************************************************************
!
!  Note separating the Doxygen comment block here so detailed decription is
!  found in the Module not the file.
!
!*******************************************************************************
      MODULE limiter_iso_t
 
      USE stel_kinds, only : rprec, cprec
      USE v3_utilities
      USE limiter
 
      IMPLICIT NONE
 
!*******************************************************************************
!  DERIVED-TYPE DECLARATIONS
!  1) extcurz base class
!
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      TYPE, EXTENDS(limiter_class) :: limiter_iso_class
         REAL (rprec), DIMENSION(0:4,0:4)   :: arz
         REAL (rprec)                       :: rc
         REAL (rprec)                       :: zc
         INTEGER                            :: numin
      CONTAINS
         PROCEDURE                          ::                                 &
     &      get_max_fval => limiter_iso_get_max_fval
         PROCEDURE                          ::                                 &
     &      get_type => limiter_iso_get_type
         PROCEDURE                          ::                                 &
     &      get_value => limiter_iso_get_value
         final                              :: limiter_iso_destruct
      END TYPE
 
!*******************************************************************************
!  INTERFACE BLOCKS
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      INTERFACE limiter_iso_class
         MODULE PROCEDURE limiter_iso_construct
      END INTERFACE
 
      CONTAINS
!*******************************************************************************
!  CONSTRUCTION SUBROUTINES
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION limiter_iso_construct(arz, rc, zc, numin, vgrid, on_edge)
 
      IMPLICIT NONE
 
!  Declare Arguments 
      class(limiter_iso_class), POINTER :: limiter_iso_construct
      REAL (rprec), DIMENSION(0:4,0:4), INTENT(in) :: arz
      REAL (rprec), INTENT(in)                     :: rc
      REAL (rprec), INTENT(in)                     :: zc
      INTEGER, INTENT(in)                          :: numin
      REAL (rprec), DIMENSION(:), INTENT(in)       :: vgrid
      LOGICAL, INTENT(in)                          :: on_edge
 
!  local variables
      REAL (rprec)                                 :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
!  First, destroy this
      ALLOCATE(limiter_iso_construct)
      
      limiter_iso_construct%arz = arz
      limiter_iso_construct%rc = rc
      limiter_iso_construct%zc = zc
      limiter_iso_construct%numin = numin
      limiter_iso_construct%on_edge = on_edge
 
      ALLOCATE(limiter_iso_construct%phi(SIZE(vgrid)))
      limiter_iso_construct%phi = vgrid
 
      CALL profiler_set_stop_time('limiter_iso_construct', start_time)
 
      END FUNCTION
 
!*******************************************************************************
!  DESTRUCTION SUBROUTINES
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      SUBROUTINE limiter_iso_destruct(this)
 
      IMPLICIT NONE
 
!  Declare Arguments 
      TYPE (limiter_iso_class), INTENT(inout) :: this
 
!  Start of executable code
 
!  Get rid of all components
      CALL limiter_destruct(this)
 
      this%arz = 0.0
      this%rc = 0.0
      this%zc = 0.0
      this%numin = 0
 
      END SUBROUTINE
 
!*******************************************************************************
!  GETTER SUBROUTINES
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION limiter_iso_get_max_fval(this, num_theta, phi_index,            &
     &                                  r, z, rphiz_at_max)
 
      IMPLICIT NONE
 
!  Declare Arguments
      REAL (rprec) :: limiter_iso_get_max_fval
      class(limiter_iso_class), INTENT(in)   :: this
         INTEGER, INTENT(in)                  :: num_theta
      INTEGER, INTENT(in)                     :: phi_index
      REAL (rprec), DIMENSION(:), INTENT(in)  :: r
      REAL (rprec), DIMENSION(:), INTENT(in)  :: z
      REAL (rprec), DIMENSION(3), INTENT(out) :: rphiz_at_max
 
!  local variables
      INTEGER                                 :: theta_index
      REAL (rprec)                            :: fval
      REAL (rprec)                            :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      limiter_iso_get_max_fval = -1.0e10
      rphiz_at_max = 0.0
 
      DO theta_index = 1, num_theta
         fval = this%get_value(r(theta_index), z(theta_index))
 
         IF (fval .gt. limiter_iso_get_max_fval) THEN
            limiter_iso_get_max_fval = fval
            rphiz_at_max = (/ r(theta_index), this%phi(phi_index),             &
     &                        z(theta_index) /)
         END IF
      END DO
 
      CALL profiler_set_stop_time('limiter_iso_get_max_fval',                  &
     &                            start_time)
 
      END FUNCTION
 
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION limiter_iso_get_value(this, r, z)
 
      IMPLICIT NONE
 
!  Declare Arguments
      REAL (rprec)                           :: limiter_iso_get_value
      class(limiter_iso_class), INTENT(in)  :: this
      REAL (rprec), INTENT(in)               :: r
      REAL (rprec), INTENT(in)               :: z
 
!  local variables
      REAL (rprec)                           :: e
      REAL (rprec)                           :: er
      REAL (rprec)                           :: ez
      REAL (rprec)                           :: grad_e
      INTEGER                                :: i
      INTEGER                                :: j
      REAL (rprec)                           :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
!  Compute function
      e = 0.0
      DO i = 0, 4
         DO j = 0, 4
            e = e                                                              &
     &        + this%arz(i,j)*((r - this%rc)**i)*((z - this%zc)**j)
         END DO
      END DO
 
!  Compute de/dr
      er = 0.0
      DO i = 1, 4
         DO j = 0, 4
            er = er                                                            &
     &         + this%arz(i,j)*i*((r - this%rc)**(i-1)) *                      &
     &           ((z - this%zc)**j)
         END DO
      END DO
 
!  Compute de/dz
      ez = 0.0
      DO i = 0, 4
         DO j = 1, 4
            ez = ez                                                            &
     &          + this%arz(i,j)*j*((r - this%rc)**i) *                         &
     &            ((z - this%zc)**(j - 1))
         END DO
      END DO
 
!  Avoid divide by zero errors.
      grad_e = max(1.e-12, sqrt(er*er + ez*ez))
      
      limiter_iso_get_value = e/grad_e
 
      CALL profiler_set_stop_time('limiter_iso_get_value', start_time)
 
      END FUNCTION
 
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION limiter_iso_get_type(this)
      USE data_parameters
 
      IMPLICIT NONE
 
!  Declare Arguments
      CHARACTER (len=data_name_length) :: limiter_iso_get_type
      class(limiter_iso_class), INTENT(in) :: this
 
!  local variables
      REAL (rprec)                          :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      limiter_iso_get_type =                                                   &
     &   trim(this%limiter_class%get_type()) // 'iso'
 
      CALL profiler_set_stop_time('limiter_iso_get_type', start_time)
 
      END FUNCTION
 
      END MODULE