signal_dot.f

Go to the documentation of this file.

!*******************************************************************************
!
!  Note separating the Doxygen comment block here so detailed decription is
!  found in the Module not the file.
!
!*******************************************************************************
 
      MODULE signal_dot
      USE stel_kinds
      USE stel_constants
      USE data_parameters
      USE profiler
 
      IMPLICIT NONE
 
!*******************************************************************************
!  signal_dot module parameters
!*******************************************************************************
      INTEGER, PARAMETER :: signal_dot_line_len = 200
 
!*******************************************************************************
!  DERIVED-TYPE DECLARATIONS
!  1) signal_dot_file base class
!
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      TYPE signal_dot_file
         PRIVATE
         INTEGER :: iou
         INTEGER :: i_line
         CHARACTER (len=6) :: signal_id
      END TYPE
 
!*******************************************************************************
!  INTERFACE BLOCKS
!*******************************************************************************
      PUBLIC  :: signal_dot_open, signal_dot_close,                            &
     &           signal_dot_parse_chord, signal_dot_read_keyword,              &
     &           signal_dot_parse_real, signal_dot_read_line
      PRIVATE :: signal_dot_check_status
 
      CONTAINS
!*******************************************************************************
!  UTILITY SUBROUTINES
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION signal_dot_open(file, signal_id)
      USE safe_open_mod
 
      IMPLICIT NONE
 
!  Declare Arguments
      TYPE(signal_dot_file)         :: signal_dot_open
      CHARACTER (len=*), INTENT(in) :: file
      CHARACTER (len=*), INTENT(in) :: signal_id
 
!  local variables
      INTEGER                       :: status
      REAL (rprec)                  :: start_time
 
!  local parameters
      INTEGER, PARAMETER            :: iou_0 = 32
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
!  Open up the file
      signal_dot_open%iou       = iou_0
      signal_dot_open%signal_id = signal_id
      CALL safe_open(signal_dot_open%iou, status, file, 'old',                 &
     &               'formatted')
      CALL signal_dot_check_status(status, signal_dot_open,                    &
     &                             'Error opening ', ' file.')
 
      CALL profiler_set_stop_time('signal_dot_open', start_time)
 
      END FUNCTION
 
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      SUBROUTINE signal_dot_close(signal_dot_file_ref)
 
      IMPLICIT NONE
 
!  Declare Arguments
      TYPE(signal_dot_file), INTENT(in) :: signal_dot_file_ref
 
!  local variables
      REAL (rprec)                      :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
!  Close the file
      CLOSE(signal_dot_file_ref%iou)
 
      CALL profiler_set_stop_time('signal_dot_close', start_time)
 
      END SUBROUTINE
 
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      SUBROUTINE signal_dot_parse_chord(signal_dot_file_ref,                   &
     &                                  coordinate_type,                       &
     &                                  chord_name,                            &
     &                                  xcart_i, xcart_f)
      USE coordinate_utilities
 
      IMPLICIT NONE
 
!  Declare Arguments
      TYPE(signal_dot_file), INTENT(inout) :: signal_dot_file_ref
      CHARACTER (len=*), INTENT(in)        :: coordinate_type
      CHARACTER (len=data_short_name_length), INTENT(out) :: chord_name
      REAL(rprec), DIMENSION(3), INTENT(out)              :: xcart_i
      REAL(rprec), DIMENSION(3), OPTIONAL, INTENT(out)    :: xcart_f
 
!  local variables
      INTEGER                              :: status
      CHARACTER (len=signal_dot_line_len)  :: line
      REAL (rprec)                         :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
!  Read the chord identification.
      line = signal_dot_read_line(signal_dot_file_ref,                         &
     &                            'Error reading ID for ', ' chord.')
      chord_name = trim(line)
 
!  Read the start position.
      xcart_i = signal_dot_parse_3_real(signal_dot_file_ref,                   &
     &                                  'Error reading start ' //              &
     &                                  'position for chord.')
 
      IF (PRESENT(xcart_f)) THEN
!  Read the end position.
         xcart_f = signal_dot_parse_3_real(signal_dot_file_ref,                &
     &                                    'Error reading end ' //              &
     &                                    'position for chord.')
      END IF
 
!  Done reading information for this chord. Generate the chord
      IF (trim(coordinate_type) .eq. 'RPHiDegZ') THEN
         xcart_i(2) = xcart_i(2)*degree ! Convert from degrees to radians.
         xcart_i = cyl_to_cart(xcart_i)
 
         IF (PRESENT(xcart_f)) THEN
            xcart_f(2) = xcart_f(2)*degree  ! Convert from degrees to radians.
            xcart_f = cyl_to_cart(xcart_f)
         END IF
      END IF
 
      CALL profiler_set_stop_time('signal_dot_parse_chord', start_time)
 
      END SUBROUTINE
 
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION signal_dot_parse_real(signal_dot_file_ref, message)
      IMPLICIT NONE
 
!  Declare Arguments
      REAL (rprec)                          :: signal_dot_parse_real
      TYPE (signal_dot_file), INTENT(inout) :: signal_dot_file_ref
      CHARACTER (len=*), INTENT(in)         :: message
 
!  local variables
      INTEGER                               :: status
      CHARACTER (len=signal_dot_line_len)   :: line
      REAL (rprec)                          :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
!  Read the start position.
      line = signal_dot_read_line(signal_dot_file_ref,                         &
     &                            'Error ', message)
!  Reread the line, looking for a single real
      READ(line, *, iostat=status) signal_dot_parse_real
      CALL signal_dot_check_status(status, signal_dot_file_ref,                &
     &                             'Error ', message)
 
      CALL profiler_set_stop_time('signal_dot_parse_real', start_time)
 
      END FUNCTION
 
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION signal_dot_parse_2_real(signal_dot_file_ref, message)
 
      IMPLICIT NONE
 
!  Declare Arguments
      REAL (rprec), DIMENSION(2)            :: signal_dot_parse_2_real
      TYPE (signal_dot_file), INTENT(inout) :: signal_dot_file_ref
      CHARACTER (len=*), INTENT(in)         :: message
 
!  local variables
      INTEGER                               :: status
      CHARACTER (len=signal_dot_line_len)   :: line
      REAL (rprec)                          :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
!  Read the start position.
      line = signal_dot_read_line(signal_dot_file_ref,                         &
     &                            'Error ', message)
!  Reread the line, looking for three reals
      READ(line, *, iostat=status) signal_dot_parse_2_real
      CALL signal_dot_check_status(status, signal_dot_file_ref,                &
     &                             'Error ', message)
 
      CALL profiler_set_stop_time('signal_dot_parse_2_real', start_time)
 
      END FUNCTION
 
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION signal_dot_parse_3_real(signal_dot_file_ref, message)
 
      IMPLICIT NONE
 
!  Declare Arguments
      REAL (rprec), DIMENSION(3)            :: signal_dot_parse_3_real
      TYPE (signal_dot_file), INTENT(inout) :: signal_dot_file_ref
      CHARACTER (len=*), INTENT(in)         :: message
 
!  local variables
      INTEGER                               :: status
      CHARACTER (len=signal_dot_line_len)   :: line
      REAL (rprec)                          :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
!  Read the start position.
      line = signal_dot_read_line(signal_dot_file_ref,                         &
     &                            'Error ', message)
!  Reread the line, looking for three reals
      READ(line, *, iostat=status) signal_dot_parse_3_real
      CALL signal_dot_check_status(status, signal_dot_file_ref,                &
     &                             'Error ', message)
 
      CALL profiler_set_stop_time('signal_dot_parse_3_real', start_time)
 
      END FUNCTION
 
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION signal_dot_parse_int(signal_dot_file_ref, message)
      IMPLICIT NONE
 
!  Declare Arguments
      INTEGER                               :: signal_dot_parse_int
      TYPE (signal_dot_file), INTENT(inout) :: signal_dot_file_ref
      CHARACTER (len=*), INTENT(in)         :: message
 
!  local variables
      INTEGER                               :: status
      CHARACTER (len=signal_dot_line_len)   :: line
      REAL (rprec)                          :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
!  Read the start position.
      line = adjustl(signal_dot_read_line(signal_dot_file_ref,                 &
     &                                    'Error ', message))
!  Reread the line, looking for a single real
      READ(line, *, iostat=status) signal_dot_parse_int
      CALL signal_dot_check_status(status, signal_dot_file_ref,                &
     &                             'Error ', message)
 
      CALL profiler_set_stop_time('signal_dot_parse_int', start_time)
 
      END FUNCTION
 
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION signal_dot_parse_2_int(signal_dot_file_ref, message)
      IMPLICIT NONE
 
!  Declare Arguments
      INTEGER, DIMENSION(2)                 :: signal_dot_parse_2_int
      TYPE (signal_dot_file), INTENT(inout) :: signal_dot_file_ref
      CHARACTER (len=*), INTENT(in)         :: message
 
!  local variables
      INTEGER                               :: status
      CHARACTER (len=signal_dot_line_len)   :: line
      REAL (rprec)                          :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
!  Read the start position.
      line = signal_dot_read_line(signal_dot_file_ref,                         &
     &                            'Error ', message)
!  Reread the line, looking for a single real
      READ(line, *, iostat=status) signal_dot_parse_2_int
      CALL signal_dot_check_status(status, signal_dot_file_ref,                &
     &                             'Error ', message)
 
      CALL profiler_set_stop_time('signal_dot_parse_2_int', start_time)
 
      END FUNCTION
 
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION signal_dot_read_keyword(signal_dot_file_ref, keywords)
 
      IMPLICIT NONE
 
!  Declare Arguments
      CHARACTER (len=data_name_length)     :: signal_dot_read_keyword
      TYPE(signal_dot_file), INTENT(inout) :: signal_dot_file_ref
      CHARACTER (len=*), DIMENSION(:), INTENT(in) :: keywords
 
!  local variables
      INTEGER                              :: i
      CHARACTER (len=signal_dot_line_len)  :: line
      REAL (rprec)                         :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
!  Contine looping until a vaild keyword is read. If the end of the file is
!  reached an error will kill the program.
      DO
         line = signal_dot_read_line(signal_dot_file_ref,                      &
     &                               'Failed to read ',                        &
     &                               ' keyword before end of file.')
         DO i = 1, SIZE(keywords)
             IF (trim(adjustl(line)) .eq. trim(keywords(i))) THEN
                signal_dot_read_keyword = keywords(i)
 
                CALL profiler_set_stop_time('signal_dot_read_keyword',         &
     &                                      start_time)
 
                RETURN
             END IF
         END DO
      END DO
 
      CALL profiler_set_stop_time('signal_dot_read_keyword', start_time)
 
      END FUNCTION
 
!*******************************************************************************
!  Private Functions and Subroutines.
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION signal_dot_read_line(signal_dot_file_ref,                       &
     &                              pre_message,                               &
     &                              post_message)
      IMPLICIT NONE
 
!  Declare Arguments
      CHARACTER (len=signal_dot_line_len)  :: signal_dot_read_line
      TYPE(signal_dot_file), INTENT(inout) :: signal_dot_file_ref
      CHARACTER (len=*), INTENT(in)        :: pre_message
      CHARACTER (len=*), INTENT(in)        :: post_message
 
!  local variables
      INTEGER                              :: status
      REAL (rprec)                         :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      READ (signal_dot_file_ref%iou, '(a)', iostat=status)                     &
     &   signal_dot_read_line
      signal_dot_file_ref%i_line = signal_dot_file_ref%i_line + 1
      CALL signal_dot_check_status(status, signal_dot_file_ref,                &
     &                             pre_message, post_message)
 
      CALL profiler_set_stop_time('signal_dot_read_line', start_time)
 
      END FUNCTION
 
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      SUBROUTINE signal_dot_check_status(status,                               &
     &                                   signal_dot_file_ref,                  &
     &                                   pre_message,                          &
     &                                   post_message)
      IMPLICIT NONE
 
!  Declare Arguments
      INTEGER, INTENT(in)                  :: status
      TYPE(signal_dot_file), INTENT(inout) :: signal_dot_file_ref
      CHARACTER (len=*), INTENT(in)        :: pre_message
      CHARACTER (len=*), INTENT(in)        :: post_message
 
!  local variables
      REAL (rprec)                         :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      IF (status .ne. 0) THEN
         WRITE(*,*) pre_message // trim(signal_dot_file_ref%signal_id)         &
     &              // post_message // ' line ',                               &
     &              signal_dot_file_ref%i_line
         stop
      END IF
 
      CALL profiler_set_stop_time('signal_dot_check_status', start_time)
 
      END SUBROUTINE
 
      END MODULE