vacuum_equilibrium.f

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!  The @header, @table_section, @table_subsection, @item and @end_table commands
!  are custom defined commands in Doxygen.in. They are defined under ALIASES.
!  For the page created here, the 80 column limit is exceeded. Arguments of
!  aliases are separated by ','. If you intended ',' to be a string you must use
!  an escaped comma '\,'.
!
!*******************************************************************************
!
!  Note separating the Doxygen comment block here so detailed decription is
!  found in the Module not the file.
!
!*******************************************************************************
 
      MODULE vacuum_equilibrium
      USE stel_kinds
      USE data_parameters
      USE biotsavart
      USE mpi_inc
      USE profiler
 
      IMPLICIT NONE
 
!*******************************************************************************
!  vacuum equilibrium module parameters
!*******************************************************************************
!  Define id's only for values that can change. All others shouldn't be needed
!  outside of the vacuum interface. Parameter id's start at 14 since 0-13 are
!  reserved for non equilibrium model parameters. These numbers will need to be
!  updated if any new model parameters are added.
 
!  Variable Parameters
      INTEGER, PARAMETER :: vacuum_extcur_id = 15
 
!*******************************************************************************
!  DERIVED-TYPE DECLARATIONS
!  1) vacuum base class
!
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      TYPE vacuum_class
         CHARACTER (len=path_length) :: vacuum_file_name
         REAL (rprec), DIMENSION(:), POINTER  :: extcur => null()
      END TYPE
 
      CONTAINS
!*******************************************************************************
!  CONSTRUCTION SUBROUTINES
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION vacuum_construct(file_name, iou)
      USE vacuum_input
 
      IMPLICIT NONE
 
!  Declare Arguments
      TYPE (vacuum_class), POINTER  :: vacuum_construct
      CHARACTER (len=*), INTENT(in) :: file_name
      INTEGER, INTENT(in)           :: iou
 
!  local variables
      TYPE (bsc_rs)                 :: bsc_rs_object
      REAL (rprec), DIMENSION(3)    :: center, mean_r
      REAL (rprec)                  :: total_current
      INTEGER                       :: i, j
      REAL (rprec)                  :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      WRITE (*,*) ' *** Initializing vacuum equilibrium from file ' //         &
     &            trim(file_name)
      WRITE (iou,*) ' *** Initializing vacuum equilibrium from file ' //       &
     &              trim(file_name)
 
      ALLOCATE(vacuum_construct)
 
      vacuum_construct%vacuum_file_name = file_name
      CALL vacuum_input_read_namelist(file_name)
 
      ALLOCATE(vacuum_construct%extcur(n_extcur))
      vacuum_construct%extcur = extcur(1:n_extcur)
 
      CALL parse_coils_file(coils_dot_file)
 
      DO i = 1, SIZE(vacuum_construct%extcur)
 
!  Compute the current averaged center of the coil group.
         center = 0.0
         total_current = 0.0
         IF (l_rot_coil_center(i)) THEN
            center = cg_rot_xcent(i,:)
         ELSE
            DO j = 1, coil_group(i)%ncoil
               total_current = total_current                                   &
     &                       + coil_group(i)%coils(j)%current
               CALL bsc_mean_r(coil_group(i)%coils(j), mean_r)
               center = center + mean_r*coil_group(i)%coils(j)%current
            END DO
            IF (total_current .ne. 0.0) THEN
               center = center/total_current
            END IF
         END IF
 
!  Generate bsc_rs for first shift, and apply it.
         CALL bsc_construct_rs(bsc_rs_object, 0.0_dp, 0.0_dp, 0.0_dp,          &
     &                         (/ 0.0_dp, 0.0_dp, 0.0_dp /),                   &
     &                         cg_shift_1(i,:))
         CALL bsc_rot_shift(coil_group(i), bsc_rs_object)
 
!  Generate bsc_rs for second shift, and apply it.
         CALL bsc_construct_rs(bsc_rs_object, cg_rot_theta(i),                 &
     &                         cg_rot_phi(i), cg_rot_angle(i),                 &
     &                         center, cg_shift_2(i,:))
         CALL bsc_rot_shift(coil_group(i), bsc_rs_object)
      END DO
 
      CALL profiler_set_stop_time('vacuum_construct', start_time)
 
      END FUNCTION
 
!*******************************************************************************
!  DESTRUCTION SUBROUTINES
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      SUBROUTINE vacuum_destruct(this)
 
      IMPLICIT NONE
 
!  Declare Arguments
      TYPE (vacuum_class), POINTER :: this
 
!  Start of executable code
      IF (ASSOCIATED(this%extcur)) THEN
         DEALLOCATE(this%extcur)
         this%extcur => null()
      END IF
 
      DEALLOCATE(this)
 
      END SUBROUTINE
 
!*******************************************************************************
!  SETTER SUBROUTINES
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      SUBROUTINE vacuum_set_param(this, id, i_index, value)
 
      IMPLICIT NONE
 
!  Declare Arguments
      TYPE (vacuum_class), INTENT(inout) :: this
      INTEGER, INTENT(in)                :: id
      INTEGER, INTENT(in)                :: i_index
      REAL (rprec), INTENT(in)           :: value
 
!  local variables
      REAL (rprec)                       :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      SELECT CASE (id)
 
         CASE (vacuum_extcur_id)
            this%extcur(i_index) = value
 
      END SELECT
 
      CALL profiler_set_stop_time('vacuum_set_param', start_time)
 
      END SUBROUTINE
 
!*******************************************************************************
!  GETTER SUBROUTINES
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION vacuum_get_param_id(this, param_name)
 
      IMPLICIT NONE
 
!  Declare Arguments
      INTEGER                         :: vacuum_get_param_id
      TYPE (vacuum_class), INTENT(in) :: this
      CHARACTER (len=*), INTENT(in)   :: param_name
 
!  local variables
      REAL (rprec)                    :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      SELECT CASE (trim(param_name))
 
         CASE ('extcur')
            vacuum_get_param_id = vacuum_extcur_id
 
         CASE DEFAULT
            WRITE (*,1000) trim(param_name)
            CALL exit(1)
 
      END SELECT
 
      CALL profiler_set_stop_time('vacuum_get_param_id', start_time)
 
1000  FORMAT('ERROR: ',a,' is not a valid parameter.')
 
      END FUNCTION
 
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION vacuum_get_param_value(this, id, i_index)
 
      IMPLICIT NONE
 
!  Declare Arguments
      REAL (rprec)                    :: vacuum_get_param_value
      TYPE (vacuum_class), INTENT(in) :: this
      INTEGER, INTENT(in)             :: id
      INTEGER, INTENT(in)             :: i_index
 
!  local variables
      REAL (rprec)                    :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      SELECT CASE (id)
 
         CASE (vacuum_extcur_id)
            vacuum_get_param_value = this%extcur(i_index)
 
         CASE DEFAULT
            vacuum_get_param_value = 0.0
 
      END SELECT
 
      CALL profiler_set_stop_time('vacuum_get_param_value', start_time)
 
      END FUNCTION
 
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION vacuum_get_param_name(this, id)
 
      IMPLICIT NONE
 
!  Declare Arguments
      CHARACTER(len=data_name_length) :: vacuum_get_param_name
      TYPE (vacuum_class), INTENT(in) :: this
      INTEGER, INTENT(in)             :: id
 
!  local variables
      REAL (rprec)                    :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      SELECT CASE (id)
 
         CASE (vacuum_extcur_id)
            vacuum_get_param_name = 'extcur'
 
         CASE DEFAULT
            stop 'Invalid vacuum parameter id.'
 
      END SELECT
 
      CALL profiler_set_stop_time('vacuum_get_param_name', start_time)
 
      END FUNCTION
 
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION vacuum_get_b_vec(this, x_cart, cyl)
      USE coordinate_utilities, ONLY : cart_to_cyl_vec
 
      IMPLICIT NONE
 
!  Declare Arguments
      REAL (rprec), DIMENSION(3)             :: vacuum_get_b_vec
      TYPE (vacuum_class), INTENT(in)        :: this
      REAL (rprec), DIMENSION(3), INTENT(in) :: x_cart
      LOGICAL, INTENT(in)                    :: cyl
 
!  local variables
      INTEGER                                :: i
      REAL (rprec), DIMENSION(3)             :: b_vec
      REAL (rprec)                           :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      vacuum_get_b_vec = 0.0
      DO i = 1, SIZE(this%extcur)
         CALL bsc_b(coil_group(i), x_cart, b_vec, this%extcur(i))
         vacuum_get_b_vec = vacuum_get_b_vec + b_vec
      END DO
 
      IF (cyl) THEN
         vacuum_get_b_vec = cart_to_cyl_vec(x_cart, vacuum_get_b_vec)
      END IF
 
      CALL profiler_set_stop_time('vacuum_get_B_vec', start_time)
 
      END FUNCTION
 
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION vacuum_get_int_b_dphi(this, r, theta)
      USE stel_constants, only: twopi
      USE coordinate_utilities, ONLY : cyl_to_cart_vec, cyl_to_cart
 
      IMPLICIT NONE
 
!  Declare Arguments
      REAL (rprec)                    :: vacuum_get_int_b_dphi
      TYPE (vacuum_class), INTENT(in) :: this
      REAL (rprec), INTENT(in)        :: r
      REAL (rprec), INTENT(in)        :: theta
 
!  local variables
      REAL (rprec), DIMENSION(3)      :: b_cart
      REAL (rprec), DIMENSION(3)      :: r_cyl
      REAL (rprec), DIMENSION(3)      :: dl
      REAL (rprec)                    :: dphi
      REAL (rprec)                    :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      vacuum_get_int_b_dphi = 0.0
 
      r_cyl(1) = r*cos(theta)
      r_cyl(2) = 0.0
      r_cyl(3) = r*sin(theta)
 
      dphi = 0.001/r_cyl(1)
      DO WHILE (r_cyl(2) .lt. twopi)
         dl = cyl_to_cart_vec(r_cyl, (/ 0.0_dp, dphi, 0.0_dp /))
         b_cart = vacuum_get_b_vec(this, cyl_to_cart(r_cyl), .false.)
         vacuum_get_int_b_dphi = vacuum_get_int_b_dphi                         &
     &                         + dot_product(b_cart, dl)
         r_cyl(2) = r_cyl(2) + dphi
      END DO
 
      CALL profiler_set_stop_time('vacuum_get_Int_B_dphi', start_time)
 
      END FUNCTION
 
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION vacuum_get_ext_currents(this, scale_currents)
 
      IMPLICIT NONE
 
!  Declare Arguments
      REAL (rprec), DIMENSION(:), POINTER :: vacuum_get_ext_currents
      TYPE (vacuum_class), INTENT(in)     :: this
      LOGICAL, INTENT(out)                :: scale_currents
 
!  local variables
      REAL (rprec)                        :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      vacuum_get_ext_currents => this%extcur
      scale_currents = .false.
 
      CALL profiler_set_stop_time('vacuum_get_ext_currents', start_time)
 
      END FUNCTION
 
!*******************************************************************************
!  QUERY SUBROUTINES
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION vacuum_is_1d_array(this, id)
 
      IMPLICIT NONE
 
!  Declare Arguments
      LOGICAL                         :: vacuum_is_1d_array
      TYPE (vacuum_class), INTENT(in) :: this
      INTEGER, INTENT(in)             :: id
 
!  local variables
      REAL (rprec)                    :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      SELECT CASE (id)
 
         CASE (vacuum_extcur_id)
            vacuum_is_1d_array = .true.
 
         CASE DEFAULT
            vacuum_is_1d_array = .false.
 
      END SELECT
 
      CALL profiler_set_stop_time('vacuum_is_1d_array', start_time)
 
      END FUNCTION
 
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION vacuum_is_recon_param(this, id)
 
      IMPLICIT NONE
 
!  Declare Arguments
      LOGICAL                         :: vacuum_is_recon_param
      TYPE (vacuum_class), INTENT(in) :: this
      INTEGER, INTENT(in)             :: id
 
!  local variables
      REAL (rprec)                    :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      SELECT CASE (id)
 
         CASE (vacuum_extcur_id)
            vacuum_is_recon_param = .true.
 
         CASE DEFAULT
            vacuum_is_recon_param = .false.
 
      END SELECT
 
      CALL profiler_set_stop_time('vacuum_is_recon_param', start_time)
 
      END FUNCTION
 
!*******************************************************************************
!  UTILITY SUBROUTINES
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      SUBROUTINE vacuum_write(this, iou)
 
      IMPLICIT NONE
 
!  Declare Arguments
      TYPE (vacuum_class), INTENT(in) :: this
      INTEGER, INTENT(in)             :: iou
 
!  local variables
      REAL (rprec)                    :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      WRITE (iou,*)
      WRITE (iou,*) 'Equilibrium Type : vacuum'
 
      CALL profiler_set_stop_time('vacuum_write', start_time)
 
      END SUBROUTINE
 
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      SUBROUTINE vacuum_write_input(this, current_step)
      USE vacuum_input
 
      IMPLICIT NONE
 
!  Declare Arguments
      TYPE (vacuum_class), INTENT(in) :: this
      INTEGER, INTENT(in)             :: current_step
 
!  local variables
      CHARACTER (len=path_length)     :: filename
      REAL (rprec)                    :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      WRITE (filename,1000) trim(this%vacuum_file_name), current_step
      CALL vacuum_input_write_namelist(trim(filename))
 
      CALL profiler_set_stop_time('vacuum_write_input', start_time)
 
1000  FORMAT(a,'_',i0.3)
 
      END SUBROUTINE
 
      END MODULE