extcurz.f

Go to the documentation of this file.

!*******************************************************************************
!
!  Note separating the Doxygen comment block here so detailed decription is
!  found in the Module not the file.
!
!*******************************************************************************
 
      MODULE extcurz
 
      USE stel_kinds, only: rprec
      USE mpi_inc
      USE profiler
      USE signal
 
      IMPLICIT NONE
 
!*******************************************************************************
!  DERIVED-TYPE DECLARATIONS
!  1) extcurz base class
!
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      TYPE, EXTENDS(signal_class) :: extcurz_class
         REAL (rprec) :: r
         REAL (rprec) :: theta
      CONTAINS
         PROCEDURE    ::                                                       &
     &      get_modeled_signal_last => extcurz_get_modeled_signal
         PROCEDURE    :: get_type => extcurz_get_type
         final        :: extcurz_destruct
      END TYPE extcurz_class
 
!*******************************************************************************
!  INTERFACE BLOCKS
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      INTERFACE extcurz_class
         MODULE PROCEDURE extcurz_construct
      END INTERFACE
 
      CONTAINS
!*******************************************************************************
!  CONSTRUCTION SUBROUTINES
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION extcurz_construct(r, theta)
 
      IMPLICIT NONE
 
!  Declare Arguments
      class(extcurz_class), POINTER :: extcurz_construct
      REAL(rprec), INTENT(in)        :: r
      REAL(rprec), INTENT(in)        :: theta
 
!  local variables
      REAL (rprec)                   :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      ALLOCATE(extcurz_construct)
      extcurz_construct%r = r
      extcurz_construct%theta = theta
 
      CALL profiler_set_stop_time('extcurz_construct', start_time)
 
      END FUNCTION
 
!*******************************************************************************
!  DESTRUCTION SUBROUTINES
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      SUBROUTINE extcurz_destruct(this)
 
      IMPLICIT NONE
 
!  Declare Arguments
      TYPE (extcurz_class), INTENT(inout) :: this
 
!  Start of executable code
      this%r = 0.0
      this%theta = 0.0
 
      END SUBROUTINE
 
!*******************************************************************************
!  GETTER SUBROUTINES
!*******************************************************************************
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION extcurz_get_modeled_signal(this, a_model, sigma,                &
     &                                    last_value)
      USE model
      USE stel_constants, only: mu0
 
      IMPLICIT NONE
 
!  Declare Arguments
      REAL (rprec), DIMENSION(4) :: extcurz_get_modeled_signal
      class(extcurz_class), INTENT(inout)    :: this
      TYPE (model_class), POINTER             :: a_model
      REAL (rprec), DIMENSION(4), INTENT(out) :: sigma
      REAL (rprec), DIMENSION(4), INTENT(in)  :: last_value
 
!  local variables
      REAL (rprec)                            :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      sigma = 0
 
      IF (btest(a_model%state_flags, model_state_vmec_flag)   .or.             &
     &    btest(a_model%state_flags, model_state_siesta_flag) .or.             &
     &    btest(a_model%state_flags, model_state_signal_flag)) THEN
         extcurz_get_modeled_signal(1) =                                       &
     &      equilibrium_get_int_b_dphi(a_model%equilibrium, this%r,            &
     &                                 this%theta)/mu0
 
         CALL this%scale_and_offset(a_model,                                   &
     &                              extcurz_get_modeled_signal(1))
      ELSE
         extcurz_get_modeled_signal = last_value
      END IF
 
      CALL profiler_set_stop_time('extcurz_get_modeled_signal',                &
     &                            start_time)
 
      END FUNCTION
 
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
      FUNCTION extcurz_get_type(this)
      USE data_parameters
 
      IMPLICIT NONE
 
!  Declare Arguments
      CHARACTER (len=data_name_length)  :: extcurz_get_type
      class(extcurz_class), INTENT(in) :: this
 
!  local variables
      REAL (rprec)                     :: start_time
 
!  Start of executable code
      start_time = profiler_get_start_time()
 
      extcurz_get_type = 'extcur'
 
      CALL profiler_set_stop_time('extcurz_get_type', start_time)
 
      END FUNCTION
 
      END MODULE